What that is, is a cyborg script. To make it into a room script is going to
take some doing and some things cant be used. Basically, what you are after
is a spotpic that talks. You wont be able to use the ON ENTER stuff or the
"come here" command because a spot pic doesnt move around. If you wanted to
test this and play with it, just copy it to a text file, name it cyborg.ipt
and swap it out with yours. YOU will become the bot to see exactly what it
does. Lemme copy this over to a text editor and work it up and test it for
you.

Jade



Ok the bot that is produced at west pole via their room I want to make into
a room script so that when peeps come in they can chat the bot and collect
av¹s from it as well can this be done?
Help! This is what I got from that room, and its used as a cyborg....smiles

;;; COPY FROM HERE DOWN ;;;

; Buddy Bot by Art Fink, 2001
; http://bots.artfink.com

ON SIGNON
{
;;; things I'll need to remember ;;;
{GLOBAL} [ myName ownerName comeHere avArray userSaid1 userSaid2 userSaid3
userSaid4 userSaid5 reply1 reply2 reply3 reply4 reply5 ownerGreet userGreet
isBot ] FOREACH

;;; names, commands, av's ;;;
"damebot" myName =
"Alan(p)+" ownerName =
"here" comeHere =
[
[918624812 918624773 918624723 918624704 918624592 918624019 952737871
-1233784404 ]
[975365788 975365836 975365843 975365799 975365900 975365828 975365773 ]
[961966237 961966292 -1222028109 961966280 961966272 -1222028257 ]
[894425242 894424691 894424850 894425195 894425087 894424681 ]
[922380565 919843623 919790240 919843534 919843389 919843352 919843152
922380430 ]
] avArray =

;;; if I hear these.. ;;;
"hello" userSaid1 =
"how are you" userSaid2 =
"where can i get av's?" userSaid3 =
"where can i get props?" userSaid4 =
"ok" userSaid5 =

;;; ..I'll reply with these ;;;
"hi there" reply1 =
"great and you?" reply2 =
"ooo i can share some with you" reply3 =
"ooo i can share some with you" reply4 =
"ok here i go" reply5 =

;;; greetings I use ;;;
"hi" userGreet =
"!" ownerName & ownerGreet =
1 isBot =
}

ON ENTER {
;;; Auto-Greet ;;;
numUsrs GLOBAL
NBRROOMUSERS numUsrs =
{ 300 ME SETALARM } greet IF
}

ON INCHAT {
;;; Globals ;;;
{GLOBAL} [ botSays myName ownerName ownerSaid comeHere greet avArray
userSaid1 userSaid2 userSaid3 userSaid4 userSaid5 reply1 reply2 reply3
reply4 reply5] FOREACH

;;; my owner said ;;;
WHOCHAT WHONAME ownerName == WHOCHAT WHONAME "^[*]" GREPSTR OR ownerSaid =

;;; my name is said ;;;
CHATSTR myName SUBSTR CHATSTR USERNAME SUBSTR OR nameSaid =

;;; my reply ;;;
"" botSays =
{
;;; owner commands ;;;
{
;;; go to owner ;;;
{ "ok" botSays = WHOCHAT WHOPOS SETPOS} CHATSTR comeHere SUBSTR IF

;;; turn greet on/off ;;;
{"ok" botSays = 1 greet = 300 ME SETALARM} CHATSTR "greet on" SUBSTR IF
{":ok" botSays = 0 greet =} CHATSTR "greet off" SUBSTR IF

;;; change avatar ;;;
{ "$1" GREPSUB ATOI 1 - avIndex =
avArray avIndex GET SETPROPS
} CHATSTR "av ([0-9]+)" GREPSTR IF
;
} ownerSaid IF

;;; Chat Replies ;;;
{reply1 botSays =} CHATSTR userSaid1 SUBSTR IF
{reply2 botSays =} CHATSTR userSaid2 SUBSTR IF
{reply3 botSays =} CHATSTR userSaid3 SUBSTR IF
{reply4 botSays =} CHATSTR userSaid4 SUBSTR IF
{reply5 botSays =} CHATSTR userSaid5 SUBSTR IF
} nameSaid WHOCHAT WHOME == NOT AND IF

;;; say reply / no flood ;;;
{ botSays SAY TICKS 60 + antiFlood = } "" botSays == NOT antiFlood TICKS <
AND IF
}

ON ALARM {
{GLOBAL} [greet numUsrs lastUserin greetMsg ownerName ownerGreet userGreet]
FOREACH
"" greetmsg =
;;; greet new user ;;;
{ NBRROOMUSERS 1 - ROOMUSER WHONAME lastUserin =
{ userGreet " " & lastUserin & greetMsg =
{ ownerGreet SAY }
{ greetMsg SAY } lastuserin ownerName == IFELSE
} numUsrs NBRROOMUSERS < IF
NBRROOMUSERS numUsrs =
300 ME SETALARM
} { BREAK } greet IFELSE
}

;;; COPY FROM HERE UP ;;;